PROGRAM SET8STAX3DTORSION
C=======================================================================
C THREE DIMENSIONAL DATA GENERATING PROGRAM FOR 3DSTATIC8QFXCOMBINE.FOR
C-------------------- TORSION PROBLEM APPLICATION ----------------------
C
C BOUNDARY CONDITIONS
C LEFT END: FIXED IN ALL DIRECTIONS
C RIGHT END: TWIST MOMENT IS APPLIED USING FORCES AT 4 POINTS
C ALL OTHERS: NO NORMAL FOECE, NO SHEAR FORCE
C DOMAIN: RECTANGULAR
C ELEMENT TYPE: 8-NODED ISOPARAMETRIC HEXA 3D ELEMENT
C DOMAIN DISCRETIZATION: ALL ELEMENTS ARE THE SAME SIZE.
C EIJI FUKUMORI JUNE 18, 2010, 09/NOV/2024
C=======================================================================
IMPLICIT REAL*8 ( A-H , O-Z )
PARAMETER ( ND=8,INTEPT=2,MXE=220000, MXN=400000, MXB=20000 )
PARAMETER (YOUNG=69.D6,POISSON=0.3D0 )
C=======================================================================
DIMENSION NODEX(MXE,ND),
* XCOORD(MXN), YCOORD(MXN) ,ZCOORD(MXN),
* IBNDFX(MXB), IBNDFY(MXB) ,IBNDFZ(MXB),
* BVX(MXB) , BVY(MXB) ,BVZ(MXB) ,
* IBFORCEX(MXB), IBFORCEY(MXB), IBFORCEZ(MXB),
* BVFORCEX(MXB), BVFORCEY(MXB), BVFORCEZ(MXB)
DIMENSION NEUTRAL(MXN), NODECTOP(MXN)
CHARACTER INPFILE*14,EXFILE*3
LOGICAL YES
C=======================================================================
DATA INPFILE / 'STATIC3D08.DAT' /
C=======================================================================
F(X) = X
G(X) = X
C=======================================================================
TLX = 20.D0
TLY = 2.D0
TLZ = 2.D0
NEX = 20
NEY = 4
NEZ = 4
C=======================================================================
C------ NEY AND NEZ MUST BE AN EVEN NUMBER.
NEY = NEY/2*2
NEZ = NEZ/2*2
C=======================================================================
DX = TLX/NEX
DY = TLY/NEY
DZ = TLZ/NEZ
NDX = NEX+1
NDY = NEY+1
NDZ = NEZ+1
C=======================================================================
C NEZ: NEMBER OF VERTICAL ELEMENTS (NUMBER OF NODES: NEZ+1)
C NEY: NEMBER OF DEPTH ELEMENTS (NUMBER OF NODES: NEY+1)
C NEX: NEMBER OF HORIZONTAL ELEMENTS (NUMBER OF NODES: NEX+1)
C=======================================================================
WRITE (*,*)' YOUNG MODULUS = ',YOUNG
WRITE (*,*)' POISSON RATIO = ',POISSON
C=======================================================================
C ELEMENT CREATION
NE = 0
DO I = 1 , NEX
DO K = 1 , NEZ
DO J = 1 , NEY
NE = NE + 1
IF ( NE .GT. MXE ) STOP 'NE > MXE'
NODEX(NE,1) = (I-1)*NDY*NDZ + (K-1)*NDY + J
NODEX(NE,2) = NODEX(NE,1) + NDY*NDZ
NODEX(NE,3) = NODEX(NE,2) + 1
NODEX(NE,4) = NODEX(NE,1) + 1
NODEX(NE,5) = NODEX(NE,1) + NDY
NODEX(NE,6) = NODEX(NE,5) + NDY*NDZ
NODEX(NE,7) = NODEX(NE,6) + 1
NODEX(NE,8) = NODEX(NE,5) + 1
END DO
END DO
END DO
WRITE (*,*) 'NUMBER OF ELEMENTS =', NE
C=======================================================================
C NODAL COORDINATE CREATION
NNODE = 0
DO I = 1 , NDX
DO K = 1 , NDZ
DO J = 1 , NDY
NNODE = NNODE + 1
IF ( NNODE .GT. MXN ) STOP 'NNODE > MXN'
XCOORD(NNODE) = (I-1)*DX
YCOORD(NNODE) = (J-1)*DY
ZCOORD(NNODE) = (K-1)*DZ
END DO
END DO
END DO
WRITE (*,*) 'NUMBER OF NODAL POINTS =', NNODE
C=======================================================================
C BOUNDARY CONDITIONS
C============================ FIRST KIND ===============================
C-------------- CONSTRAINS ARE ON THE FACE OF -X ONLY
NBFX = 0
NBFY = 0
NBFZ = 0
C-----------------------------------------------
C--------- X DIRECTION ON FACE -X
U0 = 0.D0
DO K = 1 , NDZ
DO J = 1 , NDY
NBFX = NBFX + 1
IBNDFX(NBFX) = J + (K-1)*NDY
BVX(NBFX) = U0
END DO
END DO
C-----------------------------------------------
C--------- Y DIRECTION ON FACE -X
V0 = 0.D0
DO K = 1 , NDZ
DO J = 1 , NDY
NBFY = NBFY + 1
IBNDFY(NBFY) = J + (K-1)*NDY
BVY(NBFY) = V0
END DO
END DO
C-----------------------------------------------
C--------- Z DIRECTION ON FACE -X
Z0 = 0.D0
DO K = 1 , NDZ
DO J = 1 , NDY
NBFZ = NBFZ + 1
IBNDFZ(NBFZ) = J + (K-1)*NDY
BVZ(NBFZ) = Z0
END DO
END DO
C=======================================================================
C============================ SECOND KIND ==============================
NFORCEX = 0
NFORCEY = 0
NFORCEZ = 0
C----------------- FORCES ARE ON THE FACE OF +X ONLY -------------------
FORCEINZ = 1000.D0
FORCEINY = 1000.D0
C
C--------- RIGHT END FACE
C
C <---F
C ----3---- A
C I I I
C I I I
C F 2 4 F
C I I I
C I I I
C V ----1----
C F--->
C
C
C----------- POINT 1 ---------
NFORCEY = NFORCEY + 1
IBFORCEY(NFORCEY) = NDY*NDZ*NEX + NEY/2 + 1
BVFORCEY(NFORCEY) = FORCEINY
C----------- POINT 3 ---------
NFORCEY = NFORCEY + 1
IBFORCEY(NFORCEY) = NDY*NDZ*NEX + NEZ*NDY + NEY/2 + 1
BVFORCEY(NFORCEY) = -FORCEINY
C----------- POINT 2 ---------
NFORCEZ = NFORCEZ + 1
IBFORCEZ(NFORCEZ) = NDY*NDZ*NEX + NEZ/2*NDY + 1
BVFORCEZ(NFORCEZ) = -FORCEINZ
C----------- POINT 4 ---------
NFORCEZ = NFORCEZ + 1
IBFORCEZ(NFORCEZ) = NDY*NDZ*NEX + NEZ/2*NDY + NDY
BVFORCEZ(NFORCEZ) = FORCEINZ
C=======================================================================
C DATA FILE INQUIRY
EXFILE = 'NEW'
INQUIRE ( FILE = INPFILE, EXIST = YES )
IF ( YES ) EXFILE='OLD'
C=======================================================================
C CREATING DATA FILES
C---------- PARAMETERS
OPEN ( 1, FILE=INPFILE, STATUS = 'UNKNOWN' )
WRITE(1,*) YOUNG , POISSON
C---------- ELEMENTS
WRITE(1,*) NE
DO I = 1 , NE
WRITE (1,*) I, (NODEX(I,J), J = 1 , ND )
END DO
C---------- COORDINATES OF NONAL POINTS
WRITE(1,*) NNODE
DO I = 1 , NNODE
WRITE(1,*) I,XCOORD(I), YCOORD(I), ZCOORD(I)
END DO
C--------- BOUNDARY CONDITIONS
C---------- DIRICHLET TYPE BOUNDARY CONDITIONS
WRITE(1,*) NBFX
DO I = 1 , NBFX
WRITE (1,*) IBNDFX(I), BVX(I)
END DO
WRITE(1,*) NBFY
DO I = 1 , NBFY
WRITE (1,*) IBNDFY(I), BVY(I)
END DO
WRITE(1,*) NBFZ
DO I = 1 , NBFZ
WRITE (1,*) IBNDFZ(I), BVZ(I)
END DO
C---------- NUEMANN TYPE BOUNDARY CONDITIONS
WRITE(1,*) NFORCEX
IF ( NFORCEX .GT. 0 ) THEN
DO I = 1 , NFORCEX
WRITE(1,*) IBFORCEX(I), BVFORCEX(I)
END DO
ENDIF
WRITE(1,*) NFORCEY
IF ( NFORCEY .GT. 0 ) THEN
DO I = 1 , NFORCEY
WRITE(1,*) IBFORCEY(I), BVFORCEY(I)
END DO
ENDIF
WRITE(1,*) NFORCEZ
IF ( NFORCEZ .GT. 0 ) THEN
DO I = 1 , NFORCEZ
WRITE(1,*) IBFORCEZ(I), BVFORCEZ(I)
END DO
ENDIF
C---------- FINAL
CLOSE (1)
C----------------- NODES ALONG THE NUTRAL LINE -------------------------
C---------------------- CENTER OF THE ROD --------------------------
C NODEL NUMBERS ALONG NEUTRAL LINE OF BEAM
NNEUT = 1
NEUTRAL(NNEUT) = NEZ/2*NDY + NEY/2 + 1
DO I = 1 , NEX
NNEUT = NNEUT + 1
NEUTRAL(NNEUT) = NEUTRAL(NNEUT-1) + NDY*NDZ
END DO
OPEN ( 1, FILE='NEUTRAL.DAT', STATUS = 'UNKNOWN')
WRITE (1,*) NNEUT
DO I = 1 , NNEUT
WRITE (1,*) NEUTRAL(I)
END DO
CLOSE (1)
C------------- NODES ALONG THE CENTER OF THE TOP FACE(+Z) --------------
NCTOP = 1
NODECTOP(NCTOP) = NDY*NDZ - NEY/2
DO I = 1 , NEX
NCTOP = NCTOP + 1
NODECTOP(NCTOP) = NODECTOP(NCTOP-1) + NDY*NDZ
END DO
OPEN ( 1, FILE='NODECTOP.DAT', STATUS = 'UNKNOWN')
WRITE (1,*) NCTOP
DO I = 1 , NCTOP
WRITE (1,*) NODECTOP(I)
END DO
CLOSE (1)
C=======================================================================
CALL BANDWID ( ND, MXE, NE, NODEX , NBW )
C------ CREATION OF PARAMETER FILE TO BE USED IN INCLUDE STATEMENT
OPEN ( 1, FILE='PARAM.DAT', STATUS='UNKNOWN' )
WRITE (1,*) ' PARAMETER ( ND=',ND,' )'
WRITE (1,*) ' PARAMETER ( INTEPT=',INTEPT,')'
WRITE (1,*) ' PARAMETER ( MXE=',NE,')'
WRITE (1,*) ' PARAMETER ( MXN=',NNODE,')'
WRITE (1,*) ' PARAMETER ( MXW=',NBW,')'
WRITE (1,*) ' PARAMETER ( MXB=',NBFX+NBFY+NBFZ,' )'
CLOSE (1)
C=======================================================================
OPEN ( 1, FILE='ELEMENT3D08ND.DAT', STATUS='UNKNOWN' )
C
DO IEL = 1 , NEY*NEZ
C
DO J = 1 , 4
K = J + 1
IF ( J .EQ. 4 ) K = 1
WRITE(1,*) YCOORD(NODEX(IEL,J)), ZCOORD(NODEX(IEL,J))
WRITE(1,*) YCOORD(NODEX(IEL,K)), ZCOORD(NODEX(IEL,K))
WRITE(1,*)
END DO
C
DO J = 5 , 8
K = J + 1
IF ( J .EQ. 8 ) K = 5
WRITE(1,*) YCOORD(NODEX(IEL,J)), ZCOORD(NODEX(IEL,J))
WRITE(1,*) YCOORD(NODEX(IEL,K)), ZCOORD(NODEX(IEL,K))
WRITE(1,*)
END DO
C
DO J = 1 , 4
K = J + 4
WRITE(1,*) YCOORD(NODEX(IEL,J)), ZCOORD(NODEX(IEL,J))
WRITE(1,*) YCOORD(NODEX(IEL,K)), ZCOORD(NODEX(IEL,K))
WRITE(1,*)
END DO
C
END DO
CLOSE (1)
C=======================================================================
OPEN ( 1, FILE='FORCES3D08ND.DAT', STATUS='UNKNOWN' )
WRITE (1,*) 'FORCE-DIRECTION YCOORD ZCOORD FORCE-STRENGTH'
DO I = 1 , NFORCEY
NODE = IBFORCEY(I)
WRITE (1,*) 'FORCE-Y', YCOORD(NODE), ZCOORD(NODE), BVFORCEY(I)
WRITE (1,*) 'FORCE-Y', YCOORD(NODE), ZCOORD(NODE), BVFORCEY(I)
WRITE (1,*)
END DO
DO I = 1 , NFORCEZ
NODE = IBFORCEZ(I)
WRITE (1,*) 'FORCE-Z', YCOORD(NODE), ZCOORD(NODE), BVFORCEY(I)
WRITE (1,*) 'FORCE-Z', YCOORD(NODE), ZCOORD(NODE), BVFORCEY(I)
WRITE (1,*)
END DO
CLOSE (1)
STOP 'NORMAL TERMINATION'
END
C
C
SUBROUTINE BANDWID ( ND, MXE, NE, NODEX , NBW )
IMPLICIT REAL*8 ( A-H , O-Z )
DIMENSION NODEX(MXE,ND)
NBW = 0
DO I = 1 , NE
DO J = 1 , ND-1
DO K = J+1 , ND
NBW = MAX0(NBW,IABS(NODEX(I,J)-NODEX(I,K)))
END DO
END DO
END DO
NBW = NBW + 1
WRITE(*,*) 'HALF BANDWIDTH + 1 =', NBW
RETURN
END